IPlugPaths.mm

Go to the documentation of this file.

/*
 ==============================================================================
 
 This file is part of the iPlug 2 library. Copyright (C) the iPlug 2 developers. 
 
 See LICENSE.txt for  more info.
 
 ==============================================================================
*/
 
#include "IPlugPaths.h"
#include <string>
#include <map>
 
#if defined(OS_IOS) || defined(OS_MAC)
#import <Foundation/Foundation.h>
#include <TargetConditionals.h>
#endif
 
#ifdef IGRAPHICS_METAL
extern std::map<std::string, void*> gTextureMap;
#endif
 
BEGIN_IPLUG_NAMESPACE
 
#ifdef OS_MAC
#pragma mark - macOS
 
void HostPath(WDL_String& path, const char* bundleID)
{
  @autoreleasepool
  {
    NSBundle* pBundle = [NSBundle bundleWithIdentifier: [NSString stringWithUTF8String:bundleID]];
    
    if (pBundle)
    {
      NSString* pPath = [pBundle executablePath];
      if (pPath)
      {
        path.Set([pPath UTF8String]);
      }
    }
  }
}
 
void PluginPath(WDL_String& path, PluginIDType bundleID)
{
  @autoreleasepool
  {
    NSBundle* pBundle = [NSBundle bundleWithIdentifier: [NSString stringWithUTF8String:bundleID]];
    
    if (pBundle)
    {
      NSString* pPath = [[pBundle bundlePath] stringByDeletingLastPathComponent];
      
      if (pPath)
      {
        path.Set([pPath UTF8String]);
        path.Append("/");
      }
    }
  }
}
 
void BundleResourcePath(WDL_String& path, PluginIDType bundleID)
{
  @autoreleasepool
  {
    NSBundle* pBundle = nil;
 
    if (IsAUv3AppExtensionBundleID(bundleID))
    {
      // For AUv3: use Framework bundle (appex can't access container app's resources in sandbox)
      // Derive Framework bundle ID: "xxx.AUv3" -> "xxx.AUv3Framework"
      NSString* frameworkBundleID = [[NSString stringWithUTF8String:bundleID] stringByAppendingString:@"Framework"];
      pBundle = [NSBundle bundleWithIdentifier:frameworkBundleID];
    }
    else
    {
      pBundle = [NSBundle bundleWithIdentifier:[NSString stringWithUTF8String:bundleID]];
    }
 
    NSString* pResPath = [pBundle resourcePath];
    
    path.Set([pResPath UTF8String]);
  }
}
 
void DesktopPath(WDL_String& path)
{
  NSArray* pPaths = NSSearchPathForDirectoriesInDomains(NSDesktopDirectory, NSUserDomainMask, YES);
  NSString* pDesktopDirectory = [pPaths objectAtIndex:0];
  path.Set([pDesktopDirectory UTF8String]);
}
 
void UserHomePath(WDL_String& path)
{
  NSString* pHomeDir = NSHomeDirectory();
  path.Set([pHomeDir UTF8String]);
}
 
void VST3PresetsPath(WDL_String& path, const char* mfrName, const char* pluginName, bool isSystem)
{
  NSArray* pPaths;
  if (isSystem)
    pPaths = NSSearchPathForDirectoriesInDomains(NSLibraryDirectory, NSLocalDomainMask, YES);
  else
    pPaths = NSSearchPathForDirectoriesInDomains(NSLibraryDirectory, NSUserDomainMask, YES);
  
  NSString* pApplicationSupportDirectory = [pPaths objectAtIndex:0];
  path.SetFormatted(MAX_MACOS_PATH_LEN, "%s/Audio/Presets/%s/%s/", [pApplicationSupportDirectory UTF8String], mfrName, pluginName);
}
 
void INIPath(WDL_String& path, const char* pluginName)
{
  AppSupportPath(path, false);
  path.AppendFormatted(MAX_MACOS_PATH_LEN, "/%s", pluginName);
}
 
void AppSupportPath(WDL_String& path, bool isSystem)
{
  NSArray* pPaths;
  
  if (isSystem)
    pPaths = NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSSystemDomainMask, YES);
  else
    pPaths = NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSUserDomainMask, YES);
  
  NSString *pApplicationSupportDirectory = [pPaths objectAtIndex:0];
  path.Set([pApplicationSupportDirectory UTF8String]);
}
 
void AppGroupContainerPath(WDL_String& path, const char* appGroupID)
{
  NSFileManager* mgr = [NSFileManager defaultManager];
  NSURL* url = [mgr containerURLForSecurityApplicationGroupIdentifier:[NSString stringWithUTF8String:appGroupID]];
  path.Set([[url path] UTF8String]);
}
 
void SharedMusicPath(WDL_String& path)
{
  NSArray* pPaths = NSSearchPathForDirectoriesInDomains(NSMusicDirectory, NSUserDomainMask, YES);
  NSString* pUserMusicDirectory = [pPaths objectAtIndex:0];
  path.Set([pUserMusicDirectory UTF8String]);
}
 
bool GetResourcePathFromBundle(const char* fileName, const char* searchExt, WDL_String& fullPath, const char* bundleID)
{
  @autoreleasepool
  {
    const char* ext = fileName+strlen(fileName)-1;
    while (ext >= fileName && *ext != '.') --ext;
    ++ext;
    
    bool isCorrectType = !strcasecmp(ext, searchExt);
    
    bool isAppExtension = IsAUv3AppExtensionBundleID(bundleID);
    
    NSBundle* pBundle = nil;
 
    if (isAppExtension)
    {
      // For AUv3: use Framework bundle (appex can't access container app's resources in sandbox)
      // Derive Framework bundle ID: "xxx.AUv3" -> "xxx.AUv3Framework"
      NSString* frameworkBundleID = [[NSString stringWithUTF8String:bundleID] stringByAppendingString:@"Framework"];
      pBundle = [NSBundle bundleWithIdentifier:frameworkBundleID];
    }
    else
    {
      pBundle = [NSBundle bundleWithIdentifier:[NSString stringWithUTF8String:bundleID]];
    }
 
    NSString* pFile = [[NSString stringWithUTF8String:fileName] stringByDeletingPathExtension];
    NSString* pExt = [NSString stringWithUTF8String:searchExt];
    
    if (isCorrectType && pBundle && pFile)
    {
      NSString* pBasePath = [[pBundle resourcePath] stringByAppendingString:@"/"];
 
      NSString* pPath = [[[pBasePath stringByAppendingString:pFile] stringByAppendingString: @"."] stringByAppendingString:pExt];
      
      if (pPath && [[NSFileManager defaultManager] fileExistsAtPath : pPath] == YES)
      {
        fullPath.Set([pPath UTF8String]);
        return true;
      }
    }
    
    fullPath.Set("");
    return false;
  }
}
 
bool GetResourcePathFromSharedLocation(const char* fileName, const char* searchExt, WDL_String& fullPath, const char* subfolder)
{
  @autoreleasepool
  {
    const char* ext = fileName+strlen(fileName)-1;
    while (ext >= fileName && *ext != '.') --ext;
    ++ext;
 
    bool isCorrectType = !strcasecmp(ext, searchExt);
 
    NSString* pExt = [NSString stringWithUTF8String:searchExt];
    NSString* pFile = [[[NSString stringWithUTF8String:fileName] lastPathComponent] stringByDeletingPathExtension];
      
    if (isCorrectType && pFile)
    {
      WDL_String musicPath;
      SharedMusicPath(musicPath);
 
      if (subfolder)
      {
        NSString* pPluginName = [NSString stringWithUTF8String:subfolder];
        NSString* pMusicLocation = [NSString stringWithUTF8String:musicPath.Get()];
        NSString* pPath = [[[[pMusicLocation stringByAppendingPathComponent: pPluginName] stringByAppendingPathComponent:@"Resources"] stringByAppendingPathComponent: pFile] stringByAppendingPathExtension:pExt];
 
        if ([[NSFileManager defaultManager] fileExistsAtPath : pPath] == YES)
        {
          fullPath.Set([pPath UTF8String]);
          return true;
        }
      }
    }
 
    fullPath.Set("");
    return false;
  }
}
 
EResourceLocation LocateResource(const char* name, const char* type, WDL_String& result, const char* bundleID, void*, const char* sharedResourcesSubPath)
{
  if(CStringHasContents(name))
  {
    // first check this bundle
    if(GetResourcePathFromBundle(name, type, result, bundleID))
      return EResourceLocation::kAbsolutePath;
 
    // then check ~/Music/sharedResourcesSubPath, which is a shared folder that can be accessed from app sandbox
    if(GetResourcePathFromSharedLocation(name, type, result, sharedResourcesSubPath))
      return EResourceLocation::kAbsolutePath;
    
    // finally check name, which might be a full path - if the plug-in is trying to load a resource at runtime (e.g. skin-able UI)
    NSString* pPath = [NSString stringWithUTF8String:name];
    
    if([[NSFileManager defaultManager] fileExistsAtPath : pPath] == YES)
    {
      result.Set([pPath UTF8String]);
      return EResourceLocation::kAbsolutePath;
    }
  }
  return EResourceLocation::kNotFound;
}
 
bool AppIsSandboxed()
{
  NSString* pHomeDir = NSHomeDirectory();
  
  if ([pHomeDir containsString:@"Library/Containers/"])
    return true;
  else
    return false;
}
 
bool IsXPCAuHost()
{
  return ([[[NSProcessInfo processInfo] processName] containsString:@"XPC"]);
}
 
bool IsOOPAuv3AppExtension()
{
  return ([[[NSBundle mainBundle] bundleIdentifier] containsString:@"AUv3"]);
}
 
bool IsAUv3AppExtensionBundleID(const char* bundleID)
{
  if (!bundleID)
    return false;
 
  return [[NSString stringWithUTF8String:bundleID] containsString:@".AUv3"];
}
 
#elif defined OS_IOS
#pragma mark - iOS
 
void HostPath(WDL_String& path, const char* bundleID)
{
}
 
void PluginPath(WDL_String& path, PluginIDType bundleID)
{
}
 
void BundleResourcePath(WDL_String& path, PluginIDType bundleID)
{
  NSBundle* pBundle = [NSBundle mainBundle];
    
  if(IsOOPAuv3AppExtension())
    pBundle = [NSBundle bundleWithPath: [[[pBundle bundlePath] stringByDeletingLastPathComponent] stringByDeletingLastPathComponent]];
 
  path.Set([[pBundle resourcePath] UTF8String]);
}
 
void DesktopPath(WDL_String& path)
{
}
 
void VST3PresetsPath(WDL_String& path, const char* mfrName, const char* pluginName, bool isSystem)
{
  path.Set("");
}
 
void INIPath(WDL_String& path, const char* pluginName)
{
  path.Set("");
}
 
void AppSupportPath(WDL_String& path, bool isSystem)
{
}
 
void AppGroupContainerPath(WDL_String& path, const char* appGroupID)
{
  NSFileManager* mgr = [NSFileManager defaultManager];
  NSURL* url = [mgr containerURLForSecurityApplicationGroupIdentifier:[NSString stringWithUTF8String:appGroupID]];
  path.Set([[url path] UTF8String]);
}
 
bool GetResourcePathFromBundle(const char* fileName, const char* searchExt, WDL_String& fullPath, const char* bundleID)
{
  @autoreleasepool
  {
    const char* ext = fileName+strlen(fileName)-1;
    while (ext >= fileName && *ext != '.') --ext;
    ++ext;
    
    bool isCorrectType = !strcasecmp(ext, searchExt);
    
    bool isAppExtension = IsOOPAuv3AppExtension();
    
    NSBundle* pBundle;
    
    if(isAppExtension)
      pBundle = [NSBundle bundleWithIdentifier:[NSString stringWithUTF8String:bundleID]];
    else
      pBundle = [NSBundle mainBundle];
 
    NSString* pFile = [[NSString stringWithUTF8String:fileName] stringByDeletingPathExtension];
    NSString* pExt = [NSString stringWithUTF8String:searchExt];
    
    if (isCorrectType && pBundle && pFile)
    {
      NSString* pRootPath;
      
      if (isAppExtension)
      {
        pRootPath = [[[pBundle bundlePath] stringByDeletingLastPathComponent] stringByDeletingLastPathComponent];
        #if TARGET_OS_MACCATALYST
        pRootPath = [pRootPath stringByAppendingString: @"/Resources"];
        #endif
      }
      else
      {
        pRootPath = [pBundle resourcePath];
      }
      
      NSString* pPath = [[[[pRootPath stringByAppendingString:@"/"] stringByAppendingString:pFile] stringByAppendingString: @"."] stringByAppendingString:pExt];
      
      if (pPath && [[NSFileManager defaultManager] fileExistsAtPath : pPath] == YES)
      {
        fullPath.Set([pPath UTF8String]);
        return true;
      }
    }
    
    fullPath.Set("");
    return false;
  }
}
 
EResourceLocation LocateResource(const char* name, const char* type, WDL_String& result, const char* bundleID, void*, const char*)
{
  if (CStringHasContents(name))
  {
#ifdef IGRAPHICS_METAL
    auto itr = gTextureMap.find(name);
    
    if (itr != gTextureMap.end())
    {
      result.Set(name);
      return EResourceLocation::kPreloadedTexture;
    }
#endif
    
    if (GetResourcePathFromBundle(name, type, result, bundleID))
      return EResourceLocation::kAbsolutePath;
  }
  
  return EResourceLocation::kNotFound;
}
 
bool AppIsSandboxed()
{
  return true;
}
 
bool IsXPCAuHost()
{
  // TODO: actually not allways the case if AUv3 is instantiated from framework
  return true;
}
 
bool IsOOPAuv3AppExtension()
{
  return ([[[NSBundle mainBundle] bundleIdentifier] containsString:@"AUv3"]);
}
 
#endif
 
END_IPLUG_NAMESPACE